Slow Switching of Email

 Public Function fnGetFolderIDs(folderType As Outlook.OlDefaultFolders) As String

        Dim result As String = Nothing

        Dim ns As Outlook._NameSpace = Solution_Outlook.AddinModule.CurrentInstance.OutlookApp.GetNamespace("MAPI")
        If ns IsNot Nothing Then
            Try

                Dim stores As Outlook._Stores = ns.Stores
                If stores IsNot Nothing Then
                    Try

                        ' more than 1 account - scan the Stores collection and find folders by name
                        If stores.Count > 1 Then

                            ' get name
                            Dim folder As Outlook.MAPIFolder = ns.GetDefaultFolder(folderType)
                            Dim folderName As String = folder.Name
                            Marshal.ReleaseComObject(folder)

                            ' and scan
                            For i As Integer = 1 To stores.Count
                                Try
                                    Dim store As Outlook._Store = stores(i)
                                    If store IsNot Nothing Then
                                        Try
                                            Dim root As Outlook.MAPIFolder = store.GetRootFolder()
                                            If root IsNot Nothing Then
                                                Try
                                                    Dim subfolders As Outlook._Folders = root.Folders
                                                    If subfolders IsNot Nothing Then
                                                        Try

                                                            Dim targetFolder As Outlook.Folder = CType(subfolders(folderName), Outlook.Folder)
                                                            If targetFolder IsNot Nothing Then
                                                                result = targetFolder.EntryID
                                                                GetSubFolderIDs(targetFolder, result)
                                                                Marshal.ReleaseComObject(targetFolder)
                                                            End If

                                                        Finally
                                                            Marshal.ReleaseComObject(subfolders)
                                                        End Try
                                                    End If
                                                Finally
                                                    Marshal.ReleaseComObject(root)
                                                End Try
                                            End If
                                        Finally
                                            Marshal.ReleaseComObject(store)
                                        End Try
                                    End If
                                Catch
                                    ' some stores (e.g. Public Folders) may not contain default folders
                                    ' skip the "The attempted operation failed.  An object could not be found." exception
                                End Try
                            Next

                        Else
                            ' single account, we can use the default approach
                            Dim folder As Outlook.MAPIFolder = ns.GetDefaultFolder(folderType)
                            If folder IsNot Nothing Then
                                result = folder.EntryID
                                GetSubFolderIDs(CType(folder, Outlook.Folder), result)
                                Marshal.ReleaseComObject(folder)
                            End If
                        End If

                    Finally
                        Marshal.ReleaseComObject(stores)
                    End Try
                End If

            Finally
                Marshal.ReleaseComObject(ns)
            End Try
        End If


        Return result

    End Function