HowTo: Use the View.XML property to filter Outlook items

The View object itself is simple but it has one very powerful property. This property is called XML, and it contains an xml definition of a folder view. Today we are going to look at the capabilities of the <filter> element. Using this element you can set or remove a filter for folder items programmatically.

In this sample, we filter Outlook items by one of the two fields – Subject or Body. In real projects you can use other fields as well as other conditions.

Well, let’s go. To set a filter you need to add the <filter> xml element (if it was not added before) to the <view> xml element and call the Apply method:

Private Sub btnSetFilter_Click(ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles btnSetFilter.Click
    Dim sFilter As String
    Dim CurrentExplorer As Outlook.Explorer = Nothing
    Dim CurrentView As Outlook.View = Nothing
    Dim CurrentXML As XmlDocument = New XmlDocument
    Dim CurrentFilterNodes, CurrentViewNodes As XmlNodeList
    Dim CurrentFilterNode, CurrentParentNode As XmlNode

    If TextBox1.Text.Length > 0 Then
        If rbtSubject.Checked Then
            sFilter = "urn:schemas:httpmail:subject LIKE '%" + _
            TextBox1.Text.Trim + "%'"
        Else
            sFilter = "urn:schemas:httpmail:textdescription LIKE '%" + _
            TextBox1.Text.Trim + "%'"
        End If

        CurrentExplorer = TryCast(ExplorerObj, Outlook.Explorer)
        If (CurrentExplorer IsNot Nothing) Then
            CurrentView = CurrentExplorer.CurrentView
            If (CurrentView IsNot Nothing) Then
                Try
                    CurrentXML.LoadXml(CurrentView.XML)
                    CurrentFilterNodes = _
                        CurrentXML.GetElementsByTagName("filter")
                    If CurrentFilterNodes.Count > 0 Then
                        For y As Integer = 0 _
                            To CurrentFilterNodes.Count - 1
                            CurrentFilterNode = CurrentFilterNodes(y)
                            If CurrentFilterNode.HasChildNodes Then
                                For i As Integer = _
                                CurrentFilterNode.ChildNodes.Count - 1 _
                                    To 0 Step -1
                                    CurrentFilterNode.RemoveChild( _
                                        CurrentFilterNode.ChildNodes(i))
                                Next
                            End If
                        Next
                        CurrentFilterNode = CurrentFilterNodes(0)
                        CurrentFilterNode.AppendChild( _
                            CurrentXML.CreateTextNode(sFilter))
                    Else
                        CurrentViewNodes = CurrentXML. _
                            GetElementsByTagName("view")
                        If CurrentViewNodes IsNot Nothing Then
                            CurrentParentNode = CurrentViewNodes(0)
                            CurrentFilterNode = CurrentXML. _
                                CreateElement("filter")
                            CurrentParentNode.AppendChild( _
                                CurrentFilterNode)
                            CurrentFilterNode.AppendChild( _
                                CurrentXML.CreateTextNode(sFilter))
                        End If
                    End If
                    CurrentView.XML = CurrentXML.InnerXml
                    CurrentView.Apply()
                Finally
                    Marshal.ReleaseComObject(CurrentView)
                End Try
            End If
        End If
    End If
End Sub

To remove a filter you just need to remove the <filter> element from the xml definition and call the Apply method of the View object:

Private Sub btnClearFilter_Click(ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles btnClearFilter.Click
    Dim CurrentExplorer As Outlook.Explorer = Nothing
    Dim CurrentView As Outlook.View = Nothing
    Dim CurrentXML As XmlDocument = New XmlDocument
    Dim CurrentFilterNodes As XmlNodeList
    Dim CurrentFilterNode As XmlNode

    CurrentExplorer = TryCast(ExplorerObj, Outlook.Explorer)
    If (CurrentExplorer IsNot Nothing) Then
        CurrentView = CurrentExplorer.CurrentView
        If CurrentView IsNot Nothing Then
            Try
                CurrentXML.LoadXml(CurrentView.XML)
                CurrentFilterNodes = CurrentXML. _
                    GetElementsByTagName("filter")
                If CurrentFilterNodes.Count > 0 Then
                    For y As Integer = CurrentFilterNodes.Count - 1 _
                        To 0 Step -1
                        CurrentFilterNode = CurrentFilterNodes(y)
                        If CurrentFilterNode.HasChildNodes Then
                            For i As Integer = _
                            CurrentFilterNode.ChildNodes.Count - 1 _
                              To 0 Step -1
                                CurrentFilterNode.RemoveChild( _
                                    CurrentFilterNode.ChildNodes(i))
                            Next
                        End If
                    Next
                End If
                CurrentView.XML = CurrentXML.InnerXml()
                CurrentView.Apply()
            Finally
                Marshal.ReleaseComObject(CurrentView)
            End Try
        End If
    End If
End Sub

That’s it! But that’s not the only element contained in the XML property. Good luck with the rest of them!

You may also be interested in:

Outlook customization: Reading pane, Outlook bar and To-Do bar
Creating Outlook add-in step-by-step

Available downloads:

C# sample Outlook add-in for VS 2005
VB.NET sample Outlook add-in for VS 2005